#!/usr/bin/perl -w
#
# mort - tchrist@perl.com

use strict;

use vars qw (
    $short $loan $down $years $extra $xmas $rate $months $owed $monthly
    $per_month $date $this_month $year $month $payment $paid $interest
    $td_int $td_pay $to_prince $smon $syear @monames  $from_cgi
);

@monames = qw{
    Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec
};

$loan = $down = $years = $extra = $xmas = $rate = $months = $owed =
$monthly = $per_month = $year = $month = $payment = $paid = $interest
= $td_int = $td_pay = $to_prince = 0.00;

$loan    = 200000;
$down    = "0%";
$years   = 30;
$extra   = 0;
$xmas    = 0;
$short   = 0;
$rate    = 8.75;

$from_cgi = 0;

($smon, $syear) = (localtime(time()))[4,5];
$smon += 2;

for (@ARGV) {
    my ($var, $val);
    no strict 'refs';
    if ( ($var, $val) = split /\s*=+\s*/ ) {
	unless (defined $$var) {
	    die <<EOOOPS;
$0: no var $var, please use one of
    loan, rate, down, years, extra, xmas, per_month,
    smon, and/or syear
EOOOPS
	}
	$$var = $val;
    } else {
	die "bad option: $_";
    }
}

$syear += 1900 if $syear < 100;
$date = '';

if ($down =~ s/\%$// ) {
    ($down /= 100) *= $loan;
}

for ($loan, $per_month, $down) {
    s/[\$,]//g;
    $_ += 0;
}

for ($xmas, $extra) {
    s/,//g;
    $_ += 0;
}

$owed = $loan - ($paid = $down);

$months  = $years * 12;
$monthly = $rate / 12;
for ($rate, $monthly) { $_ /= 100 }

$per_month ||= $owed * ( $monthly / ( 1 - ( 1 + $monthly ) ** -$months ) );

format STDOUT_TOP =
@||||||| @|||| @||||||||  @||||||||  @||||||||  @||||||||  @||||||||  @||||||||||  @||||||||||
'Date', 'Pay#', 'Pay Now', 'Interest', 'To Main', 'YTD Pay', 'YTD Int', 'Still Owed', 'Total Paid'
.

format STDOUT =
@||||||| @>>>  @>>>>>>>>  @>>>>>>>>  @>>>>>>>>  @>>>>>>>>  @>>>>>>>>  @>>>>>>>>>>  @>>>>>>>>>>
{
$date,   $month,
	       commify($payment),
			  commify($interest),
				     commify($to_prince),
						commify($td_pay),
							   commify($td_int),
								      commify($owed),
										    commify($paid)
}
.

$^L = '';

$date = '<B>Initial<BR>Loan</B>' if $from_cgi;

if ($from_cgi) {
    printf "<H1 ALIGN=CENTER>Mortgage Calculation Results</H1>";
    print "<UL>";
    print "<LI>Total Price: \$", commify($loan);
    print "<LI>Down Payment: \$", commify($down);
    printf "<LI>Annual Interest Rate: %.03f%%", 100 * $rate;
    print "<LI>Years: ", $years;
    print "<LI>Normal monthly payment: \$", commify($per_month);

    if ($extra) {
	print "<LI>Extra Payments: $extra";
	if ($extra !~ /\$/) {
	    print " extra payment";
	    print "s" if $extra != 1;
	    print " distributed thoughout the year";
	}
    }

    if ($xmas) {
	print "<LI>Extra per Year: $xmas";
	if ($xmas !~ /\$/) {
	    print " extra payment";
	    print "s" if $xmas != 1;
	    print " at end of year";
	}
    }

    print "</UL><HR>";

    table_header();
    table_write();
} else {
    write;
}

sub table_header {
    print "<P><TABLE BORDER CELLPADDING=2>";
    print "<TR>";
    for ( 'Month', 'Pay #', 'Pay Now', 'Interest', 'Principal',
	    'YTD Paid', 'YTD Intrst', 'Still Owed', 'Total Paid' )
    {
	print "<TH>$_</TH>\n";
    }
    print "</TR>";
}


for ( $month = 1; $owed > 0; $month++ ) {
    $payment = $per_month;
    $this_month =  -1 + ($smon + $month) % 12;
    $year =  $syear + int (($smon + $month - 2) / 12);

    if ($extra =~ m/\$(.+)/) {
	$payment += $1;
    } else {
	$payment += ($per_month * $extra/12);
    }

    if ($xmas && $this_month % 12 == 0) {
	if ($xmas =~ m/\$(.+)/) {
	    $payment += $1;
	} else {
	    $payment += $per_month * $xmas;
	}
    }

    $payment = sprintf("%.2f", $payment);  # can only pay in integer pennies
    $interest = $owed * $monthly;

    $td_int += $interest;
    $td_pay += $payment;
    if ($interest + $owed < $payment) { $payment = $owed + $interest; }
    $to_prince = $payment - $interest;
    $owed -= $to_prince;
    $paid += $payment;

    $date = sprintf "%3s %04d", $monames[$this_month-1], $year;


    if (!$short || $this_month % 12 == 0 || $owed < 0.01) {
	if ($owed < 0.01) {
	    $date .= "<BR><B>Final Balance</b>" if $from_cgi;
	}
	unless ($from_cgi) {
	    write;
	} else {
	    table_write();
	    if ($this_month % 12 == 0 && !$short) {
		table_footer();
		table_header();
	    }
	}
    }

    if ($this_month % 12 == 0) {
	$td_pay = $td_int = 0;
	$- = 0 unless $short;
    }

    # print "Backsliding! Paying $to_prince to principal" if $to_prince < 0;
}


if ($from_cgi) {
    table_footer();
    print "<HR>";
    print "<H1 ALIGN=CENTER>Congratulations!</H1> You just paid <b><big>\$", commify($paid - $loan),
	    "</b></big> in (deductable) interest for that <b><big>\$", commify($loan), "</b></big>  loan!";

} 

sub table_footer {
    print "<CAPTION><B><I>Payments through $year</I></B></CAPTION>";
    print "</TABLE>";
}

sub commify {
    local $_ = sprintf "%.2f", shift;
    1 while s/^(-?\d+)(\d{3})/$1,$2/;
    return $_;
}

sub table_write {
    print "<TR>";
    print "<TD ALIGN=RIGHT>$date</TD>";
    print "<TD ALIGN=RIGHT>$month</TD>";
    for ( $payment, $interest, $to_prince, $td_pay, $td_int, $owed, $paid ) {
	print "<TD ALIGN=RIGHT>", commify($_), "</TD>";
    }
    print "</TR>\n";
}