#!/usr/bin/perl
#
# ndf -- perl reimplementation of df
#
# tchrist@mox.perl.com
#	 v1.?

require 5.001;  # not sure whether this is so

# modules used: English, Getopt::Std (standard), dfent (supplied)

parse_options();
gen_output();
exit ($errors != 0);

############################################################################

sub parse_options {
    use Getopt::Std;
    getopts("5pblait:") || usage("Bad option");

    if ($opt_b + $opt_i + $opt_5 + $opt_l + $opt_p > 1) {
	usage("More than one of -[bi5lp] specified");
    } 

    $just_inode  = $opt_i;
    $sys5	 = $opt_5;
    $bsd	 = $opt_b || 1;
    $long_form   = $opt_l;
    $parsable    = $opt_p;

    $want_type   = $opt_t;
    $even_boring = $opt_a;

    use English;
    ($FORMAT_NAME, $FORMAT_TOP_NAME) = do {
	if    ($long_form) 	{ qw( Long	Long_Top   ) }
	elsif ($just_inode)	{ qw( Inodes 	Inodes_Top ) }
	elsif ($sys5) 		{ qw( SysV 	SysV_Top   ) }
	elsif ($bsd)		{ qw( BSD 	BSD_Top    ) }
	else 			{ die " No format?" 	     } 
    };

}

#####################################

sub usage {
    warn "$0: @_\n" if @_;
    die <<EOF;

Usage: $0 [-l] [-a] [-i] [-t type] [filesystem ...] [filename ...]

    -b		block info in BSD format (DEFAULT)
    -i		inode info only in BSD format
    -5		SysV "df -t" output: half-K blocks plus inodes
    -l 		long format - list everything

    -a		even systems with no blocks
    -t type	just filesytems of this type

    -p		output long format in parsable form; fields are 
		separated by "=" signs, and are in this order:
		  filesystem 
		      kbytes ubytes kavail kcapacity 
		      inodes iavail icapacity 
		  mntpt

EOF
}

#####################################

sub gen_output {
    use SYS::dfent qw(&getdfname &fetch_mountpoints
			$filesystem $mountpoint $type
			$kbytes $ubytes $kused $kavail $kcapacity 
			$inodes $iavail $iused $icapacity 
		);


    @ARGV = fetch_mountpoints() unless @ARGV;

    ARG: for $arg (@ARGV) {

	unless ($fsi = getdfname($arg)) { 
	    warn "$0: Problem looking up $arg: $!\n";
	    $errors++;
	    next ARG;
	}

	use SYS::stat qw(stat);
	$bsize = stat($arg)->blksize() / 1024 . 'k';

	next if $want_type && $type !~ /\b\Q$want_type\E\b/o;

	next ARG unless $kbytes or $even_boring;

	if ($parsable) { 
	    print join('=', 
			$filesystem, 
			$kbytes, $ubytes, $kavail, $kcapacity, 
			$inodes, $iavail, $icapacity, 
			$mountpoint
		      ), "\n";
	} else { 
	    if (length($filesystem) > 18) {
		# painful hack
		print "$filesystem\n";
		$filesystem = '';
	    } 
	    write;
	}
    }

}


#################################################################
### standard format
###################
format BSD_Top =
Filesystem            kbytes    used   avail capacity  Mounted on
.

format BSD =
@<<<<<<<<<<<<<<<<<< @>>>>>>> @>>>>>> @>>>>>>   @>>>    @*
$filesystem,	    $kbytes, $kused,  $kavail,  $kcapacity.'%', $mountpoint
.

#################################################################
### -i flag
####################
format Inodes_Top =
Filesystem          bsize    iused   ifree  %iused  Mounted on
.

format Inodes =
@<<<<<<<<<<<<<<<<<< @>>>> @>>>>>>> @>>>>>>   @>>>   @*
$filesystem,	    $bsize, $iused,  $iavail, $icapacity.'%', $mountpoint
.

#################################################################
### -5 flag
#################
format SysV_Top =
Filesystem            bavail  iavail  btotal  itotal  Mounted on
.

format SysV =
@<<<<<<<<<<<<<<<<<< @>>>>>>> @>>>>>> @>>>>>> @>>>>>>  @*
$filesystem,	    $kavail*2,$iavail,$kbytes*2,$inodes,$mountpoint
.

#################################################################
### -l flag
#################
format Long_Top =
Filesystem          kroot   kuser   kfree   k%  itotal  ifree   i% Mounted on
.

format Long =
@<<<<<<<<<<<<<<< @>>>>>>> @>>>>>> @>>>>>> @>>>  @>>>>> @>>>>> @>>> @*
{
$filesystem,	    $kbytes, $ubytes, 
				     $kavail,$kcapacity.'%', 
						$inodes,$iavail,$icapacity.'%',
								   $mountpoint
}
.